update-script bu şekilde.
# AOSPA GApps Installation Script - Updated: 2014-01-23
ui_print(" ");
ui_print("###########################################");
ui_print(" ___ _ ___ _ ");
ui_print(" | _ \ /_\ / __| /_\ _ __ _ __ ___ ");
ui_print(" | _// _ \ | (_ | / _ \ | '_ \| '_ \(_-< ");
ui_print(" |_| /_/ \_\ \___|/_/ \_\| .__/| .__//__/ ");
ui_print(" |_| |_| ");
ui_print("###########################################");
ui_print(" ");
ui_print("PA GApps Modular-Mini 4.4.2 - 20140123");
ui_print(" ");
sleep(3);
ui_print("Mounting system...");
run_program("/sbin/busybox", "mount", "/system");
ui_print(" ");
# Checking to make certain user has a 4.4.x ROM Installed - If not, we abort
ifelse(
is_substring("4.4", file_getprop("/system/build.prop","ro.build.version.release")),
(
ui_print("Android 4.4.x ROM detected");
ui_print(" ");
),
(
ui_print("**** Incompatible Android ROM detected ****");
ui_print(" ");
ui_print("This GApps package is for Android 4.4.x ONLY");
ui_print(" ");
ui_print("******** GApps Installation failed *******");
ui_print(" ");
ui_print("Unmounting system...");
run_program("/sbin/busybox", "umount", "/system");
ui_print(" ");
sleep(7);
abort("Aborting...");
)
);
show_progress(0.8,25);
# Extract required package files to /tmp and run the preparation script
package_extract_file("system/etc/g.prop", "/tmp/g.prop");
package_extract_file("delete-list.txt", "/tmp/delete-list.txt");
package_extract_file("gapps-list.txt", "/tmp/gapps-list.txt");
package_extract_file("install-prep.sh", "/tmp/install-prep.sh");
set_perm(0, 0, 0777, "/tmp/install-prep.sh");
run_program("/tmp/install-prep.sh", file_getprop("/tmp/g.prop","ro.addon.pa_type"), file_getprop("/tmp/g.prop","ro.addon.pa_size"), file_getprop("/tmp/g.prop","ro.addon.pa_version"), file_getprop("/system/build.prop","ro.product.device"));
# Check that sufficient space exists in the system partition to install this GApps
# Calculations should be extremely accurate and include a 10MB buffer to allow for ROM growth
ifelse(
less_than_int(file_getprop("/tmp/gapps.prop","free_system_size_kb"), file_getprop("/tmp/gapps.prop","free_space_reqd_kb")),
(
ui_print("Insufficient storage space available in");
ui_print("System partition. You may want to use a");
ui_print("smaller GApps (i.e. Micro GApps)");
ui_print(" ");
ui_print("If you have further questions, please");
ui_print("post the pa_gapps.txt file that has been");
ui_print("copied to /sdcard.");
ui_print(" ");
ui_print("******* GApps Installation failed *******");
ui_print(" ");
ui_print("Unmounting system...");
run_program("/sbin/busybox", "umount", "/system");
ui_print(" ");
sleep(15);
abort("Aborting...");
)
);
# Removing pieces that may be left over from other GApps or ROM's
delete(
"/system/app/BrowserProviderProxy.apk",
"/system/app/Calendar.apk",
"/system/app/Gmail.apk",
"/system/app/GmsCore.apk",
"/system/app/GoogleCalendar.apk",
"/system/app/GoogleCalendarSyncAdapter.apk",
"/system/app/GoogleHangouts.apk",
"/system/app/GooglePlus.apk",
"/system/app/PartnerBookmarksProvider.apk",
"/system/app/QuickSearchBox.apk",
"/system/app/Talk.apk",
"/system/app/Vending.apk",
"/system/app/Youtube.apk",
"/system/priv-app/Calendar.apk",
"/system/priv-app/GmsCore.apk",
"/system/priv-app/GoogleNow.apk",
"/system/priv-app/OneTimeInitializer.apk",
"/system/priv-app/QuickSearchBox.apk",
"/system/priv-app/Vending.apk"
);
# Remove apps from 'app' that need to be installed in 'priv-app'
delete(
"/system/app/CalendarProvider.apk",
"/system/app/GoogleBackupTransport.apk",
"/system/app/GoogleFeedback.apk",
"/system/app/GoogleLoginService.apk",
"/system/app/GoogleOneTimeInitializer.apk",
"/system/app/GooglePartnerSetup.apk",
"/system/app/GoogleServicesFramework.apk",
"/system/app/OneTimeInitializer.apk",
"/system/app/Phonesky.apk",
"/system/app/PrebuiltGmsCore.apk",
"/system/app/SetupWizard.apk",
"/system/app/talkback.apk",
"/system/app/Velvet.apk"
);
# Remove .odex files from early 4.4 GApps packages
delete(
"/system/app/CalendarGoogle.odex",
"/system/app/GenieWidget.odex",
"/system/app/Gmail2.odex",
"/system/app/GoogleContactsSyncAdapter.odex",
"/system/app/GoogleEars.odex",
"/system/app/GoogleTTS.odex",
"/system/app/Keep.odex",
"/system/app/LatinImeGoogle.odex",
"/system/app/MediaUploader.odex",
"/system/framework/com.google.android.maps.odex",
"/system/framework/com.google.android.media.effects.odex",
"/system/framework/com.google.widevine.software.drm.odex",
"/system/priv-app/CalendarProvider.odex",
"/system/priv-app/GoogleBackupTransport.odex",
"/system/priv-app/GoogleFeedback.odex",
"/system/priv-app/GoogleLoginService.odex",
"/system/priv-app/GooglePartnerSetup.odex",
"/system/priv-app/GoogleServicesFramework.odex",
"/system/priv-app/OneTimeInitializer.odex",
"/system/priv-app/SetupWizard.odex"
);
# Removing libs that are no longer included with Google+ (check to make certain it doesn't show up in another app)
delete("/system/lib/libstlport_shared.so","/system/lib/libfacetracker.so","/system/lib/libfrsdk.so");
# Removing MediaUploader (since Google removed it beginning with 4.4.1)
delete("/system/app/MediaUploader.apk");
# Removals COMPLETE - On to the installation process
# Main install process - copying over system files
ui_print("Installing GApps...");
ui_print(" ");
package_extract_dir("system", "/system");
# FaceUnlock install process - copying over system files
ifelse(
file_getprop("/tmp/gapps.prop","install.faceunlock") == "true",
(
ui_print("Installing FaceUnlock...");
ui_print(" ");
# Remove stock .odex file from early 4.4 GApps packages
delete("/system/app/FaceLock.odex");
package_extract_dir("optional/face", "/system");
set_perm(0, 0, 0755, "/system/addon.d/71-faceunlock.sh");
)
);
show_progress(0.2, 6);
ui_print("Fixing Permissions...");
ui_print(" ");
set_perm(0, 0, 0755, "/system/addon.d/70-gapps.sh");
set_perm_recursive(0, 0, 0755, 0644, "/system/app");
set_perm_recursive(0, 0, 0755, 0644, "/system/priv-app");
ui_print("Unmounting system...");
ui_print(" ");
run_program("/sbin/busybox", "umount", "/system");
ui_print("GApps Installation Complete!");
ui_print(" ");
sleep(3);
